This webpage uses JavaScript crypto currency mining in order to support the maintenance and the development of open-source software.

(%i1) load("/home/vcaeken/Desktop/rfMaxima.mac")$

Result

Waveguide Loss (TE-10 Mode)

(See "A W-band waveguide fabricated using selective laser melting, by K. Van Caekenberghe et al.,
Wiley Microwave and Optical Technology Letters, vol. 54, no. 11, p. 2572–2575, Nov. 2012)

1 Constants

(%i2) %epsilon_0:8.854e-12$
%mu_0:4*%pi*1e-7$
%eta:float(sqrt(%mu_0/%epsilon_0));
c:float(sqrt(1/(%epsilon_0*%mu_0)));
k(f):=2*%pi*f/c;

Result

2 Design Characteristics

2.1 Material Parameters

(%i7) %sigma_Au:41000410$
%sigma_Cu:5.8e7$
%sigma_Ti6Al4V:5.8e5$
R_q:1.25e-6$

2.2 Waveguide Dimensions

WR-28 26.5-40 GHz 0.28 x 0.14 inch
WR-10 75-110 GHz 0.1 x 0.05 inch
WR-3 220-325 GHz 0.034 x 0.017 inch

(%i11) a:0.1*0.0254$
b:0.05*0.0254$
t:0.01*0.0254$
f_0:94e9$

3 Complex Propagation Constant, Wave Impedance

(%i15) %lambda_c:2*a;
f_c:c/(2*a);
%delta(%mu,%sigma,%omega):=sqrt(2/(%omega*%mu*%sigma));
R_s(%delta,%sigma):=1/(%sigma*%delta);
define(%alpha(%mu,%sigma,f),block(
    [%delta],
    %delta:%delta(%mu,%sigma,2*%pi*f),
    ratsimp(R_s(%delta,%sigma)/(a^3*b*%beta(f)*k(f)*%eta)*(2*b*%pi^2+a^3*k(f)^2))));
%beta(f):=sqrt(k(f)^2-(%pi/a)^2);
Z_TE10(f):=k(f)*%eta/%beta(f);

Result

3.1 Figures of Merit without Surface Roughness

(%i22) wxplot2d(%delta(%mu_0,%sigma_Ti6Al4V,2*%pi*f*1e9),
    [f,1,100],
    [logx],
    [legend,false],
    [xlabel,"Frequency [GHz]"],
    [ylabel,"%delta [m]"],
    [style,[lines,3,11]],
    [gnuplot_preamble,"set grid"])$

Result

(%i23) wxplot2d(8.868*%alpha(%mu_0,%sigma_Ti6Al4V,f*1e9),
    [f,75,110],
    [legend,false],
    [xlabel,"Frequency [GHz]"],
    [ylabel,"%alpha [dB/m]"],
    [style,[lines,3,11]],
    [gnuplot_preamble,"set grid"])$

Result

(%i24) wxplot2d(%beta(f*1e9),
    [f,75,110],
    [legend,false],
    [xlabel,"Frequency [GHz]"],
    [ylabel,"%beta [rad/s]"],
    [style,[lines,3,11]],
    [gnuplot_preamble,"set grid"])$

Result

(%i25) wxplot2d(Z_TE10(f*1e9),
    [f,75,110],
    [legend,false],
    [xlabel,"Frequency [GHz]"],
    [ylabel,"Z_TE10 [rad/s]"],
    [style,[lines,3,11]],
    [gnuplot_preamble,"set grid"])$

Result

3.2 Figures of Merit with Surface Roughness

References:
- Ansoft HFSS 11, HFSS Online Help - Technical Notes, p 16-84

(%i26) K_w(%delta,R_q):=1+exp(-(%delta/(2*R_q))^1.6);
%sigma_c(%sigma,K_w):=%sigma/K_w^2;

Result

(%i28) f_c;
float(Z_TE10(f_0));
float(%delta(%mu_0,%sigma_Ti6Al4V,2*%pi*f_0));
float(R_s(%delta(%mu_0,%sigma_Ti6Al4V,2*%pi*f_0),%sigma_Ti6Al4V));
float(8.868*%alpha(%mu_0,%sigma_Ti6Al4V,f_0));
float(K_w(%delta(%mu_0,%sigma_Ti6Al4V,2*%pi*f_0),R_q));
float(%sigma_Ti6Al4V_rough:%sigma_c(%sigma_Ti6Al4V,K_w(%delta(%mu_0,%sigma_Ti6Al4V,2*%pi*f_0),R_q)))$
float(R_s(%delta(%mu_0,%sigma_Ti6Al4V,2*%pi*f_0),%sigma_Ti6Al4V_rough));
float(8.868*%alpha(%mu_0,%sigma_Ti6Al4V_rough,f_0));

Result

(%i37) wxplot2d([%sigma_Ti6Al4V,%sigma_c(%sigma_Ti6Al4V,K_w(%delta(%mu_0,%sigma_Ti6Al4V,2*%pi*f),R_q))],
    [f,1e6,1e11],
    [logx],
    [legend,false],
    [xlabel,"Frequency [Hz]"],
    [ylabel,"%sigma [S/m]"],
    [style,[lines,3,1],[lines,3,2]],
    [gnuplot_preamble,"set grid"])$

Result

(%i38) wxplot2d([8.868*%alpha(%mu_0,%sigma_Ti6Al4V,f*1e9),8.868*%alpha(%mu_0,%sigma_c(%sigma_Ti6Al4V,K_w(%delta(%mu_0,%sigma_Ti6Al4V,2*%pi*f*1e9),R_q)),f*1e9)],
    [f,75,110],
    [legend,false],
    [xlabel,"Frequency [GHz]"],
    [ylabel,"%alpha [dB/m]"],
    [style,[lines,3,11]],
    [gnuplot_preamble,"set grid"])$

Result

4 S-Parameters

(%i39) l:0.05$

define(S_WG(f),
    ABCD2S(block(
        Z_0:Z_TE10(f),
        ABCD_LossyTL(
            %alpha(%mu_0,%sigma_c(%sigma_Ti6Al4V,K_w(%delta(%mu_0,%sigma_Ti6Al4V,2*%pi*f),R_q)),f)+%i*%beta(f),
            l,
            Z_TE10(f)))))$

Result

(%i41) PlotSmithChart([
    parametric,
    realpart(S_WG(f)[1,1]),
    imagpart(S_WG(f)[1,1]),
    [f,75e9,110e9],
    [nticks,100]]);

Result

(%i42) PlotSmithChart([
    parametric,
    realpart(S_WG(f)[2,1]),
    imagpart(S_WG(f)[2,1]),
    [f,75e9,110e9],
    [nticks,100]]);

Result


Created with wxMaxima.